#!/bin/csh -f
## ###################################################################### ##
##         Copyright IBM Corporation 1988,1991 - All Rights Reserved      ##
##        For full copyright information see:'andrew/config/COPYRITE'     ##
## ###################################################################### ##

if ($#argv == 0) then
	set OBJDIR=.
else
	set OBJDIR=$1
endif
cd ${OBJDIR}
if (! -e Imakefile) then
	echo "==>>> No Imakefile - Cannot Generate Makefile <<<=="
	exit(1)
endif
set DIR=`pwd | tr '/' ' '`
set TOP=`echo /usr/andrew | tr '/' ' '`
set IMAKE = /usr/bin/X11/imake
if ($#TOP > $#DIR) then
	set MAX=$#DIR
else
	set MAX=$#TOP
endif
set LIMIT=$#DIR
set COUNT=1
while (${COUNT} < ${MAX} && ("${TOP[${COUNT}]}" == "${DIR[${COUNT}]}"))
	@ COUNT++
end
set REL="."
while (${LIMIT} >= ${COUNT})
	set REL=${REL}/..
	@ LIMIT--
end
switch (${COUNT})
	case 1:
	    set REL=${REL}/usr/andrew
	    breaksw
	case 2:
	    set REL=${REL}/andrew
	    breaksw
	default:
		echo "==>>> I do not know where you are <<<=="
		echo "==>>> exiting <<<=="
		exit(-1)
endsw
echo "##### Generating Makefile with Relative Path:"
echo "	${REL}"
${IMAKE} -T imake.tmpl -I${REL} -I${REL}/config -s Makefile -DTOPDIR=${REL}

